mIRC highlight manager

Moderator: GeekShed.Net Staff

mIRC highlight manager

Postby GrimReaper » Mon Aug 16, 2010 4:12 pm

How to get it to work:

First of all, Take the code below and load it into a blank remote file.
Second, Right click anywhere you choose and select "Highlight Manager V 1.0"

Then select "Add HL" and input a word you'd like to use as a highlight. Then press "Ok"..

After that you'd want to select how your "selected highlight" should be shown. i.e, Popups, Beeps or window flashing. Or all three.

Then you are basically done.

Code: Select all
#highlight on
on *:TEXT:*:#: {
  if (%hl.enable == on) {
    if ($istok(%hl.names,$1-,44)) || ($me isincs $1-) {
      if (%hl.tips) { noop $tip(Highlight,Highlight,You have been highlighted! $crlf $+ Network: $network $crlf $+ Nick: $nick $crlf $+ Time: $time(hh:nn tt) $crlf $+ Channel: $chan,5,,,,) }
      if (%hl.window) {
        .window @highlight. [ $+ [ $network ] ]
        aline @highlight. [ $+ [ $network ] ] Highlight by $nick at $time(hh:nn tt) on $chan $+ : $1-
      }
      if (%hl.beeps) { .beep 5 }
    }
  }
}
#highlight end

menu @highlight.* {
  -
  Clear Window:clear
  -
}

ctcp 1:hlmngr:.ctcpreply $nick hlmngr Highlight Manager V 1.0 by GrimReaper & Zetacon.

menu * {
  Highlight Manager V 1.0:highlightmanager
}

dialog hlmanager {
  title "Highlight Manager"
  size -1 -1 134 103
  option dbu
  box "Highlights:", 3, 2 2 64 99
  list 4, 5 11 58 86, size autovs
  box "Options:", 5, 68 2 64 99
  button "Add HL", 6, 71 12 27 12
  button "Del HL", 7, 102 12 27 12
  button "Edit HL", 8, 71 27 27 12
  button "Test $tip", 9, 102 27 27 12
  button "Ok", 10, 71 85 27 12
  button "Cancel", 11, 102 85 27 12
  check "Enable Highlights?", 12, 71 42 53 10
  check "Windows?", 13, 71 52 50 10
  check "$tip windows?", 14, 71 62 50 10
  check "Beeps?", 15, 71 72 50 10
  menu "File", 1
  item "Close", 2, 1
}

on *:DIALOG:hlmanager:init:*: {
  if (!%hl.enable) { did -b $dname 6,7,8,9,13,14,15 }
  if (%hl.enable) {
    did -c $dname 12
    if (%hl.window) { did -c $dname 13 }
    if (%hl.tips) { did -c $dname 14 }
    if (%hl.beeps) { did -c $dname 15 }
    var %a = 1
    while (%a <= $numtok(%hl.names,44)) {
      did -a $dname 4 $gettok(%hl.names,%a,44)
      inc %a
    }
  }
}

on *:DIALOG:hlmanager:sclick:6-15: {
  if ($did == 12) {
    if ($did(12).state == 0) { unset %hl.enable | did -r $dname 4 | did -b $dname 6-9,13-15 | .disable #highlights }
    if ($did(12).state == 1) {
      .enable #highlights
      did -e $dname 6-9,13-15
      set %hl.enable on
      var %a = 1
      while (%a <= $numtok(hl.names,44)) {
        did -a $dname 4 $gettok(%hl.names,%a,44)
        inc %a
      }
      if (%hl.window) { did -c $dname 13 }
      if (%hl.tips) { did -c $dname 14 }
      if (%hl.beeps) { did -c $dname 15 }
    }
  }
  if ($did == 13) {
    if ($did(13).state == 0) { unset %hl.window }
    if ($did(13).state == 1) { set %hl.window on }
  }
  if ($did == 14) {
    if ($did(14).state == 0) { unset %hl.tips }
    if ($did(14).state == 1) { set %hl.tips on }
  }
  if ($did == 15) {
    if ($did(15).state == 0) { unset %hl.beeps }
    if ($did(15).state == 1) { set %hl.beeps on }
  }
  if ($did == 6) {
    did -r $dname 4
    set %hl.names $addtok(%hl.names,$$?="Please enter a highlight word:",44)
    var %a = 1
    while (%a <= $numtok(%hl.names,44)) {
      did -a $dname 4 $gettok(%hl.names,%a,44)
      inc %a
    }
  }
  if ($did == 7) {
    if (!$did(4).sel) { noop $input(Please select a word to delete.,owu,Error!) }
    else {
      unset %hl.names
      did -d $dname 4 $did(4).sel
      var %a = 1
      while (%a <= $did(4).lines) {
        set %hl.names $addtok(%hl.names,$did($dname,4,%a).text,44)
        inc %a
      }
    }
  }
  if ($did == 8) {
    if (!$did(4).sel) { noop $input(Please select a nick to edit.,owu,Error!) }
    else {
      set %hl.names $deltok(%hl.names,$did(4).sel,44)
      did -r $dname 4
      set %hl.names $addtok(%hl.names,$$?="Please enter a new highlight:",44)
      var %a = 1
      while (%a <= $numtok(%hl.names,44)) {
        did -a $dname 4 $gettok(%hl.names,%a,44)
        inc %a
      }
    }
  }
  if ($did == 9) {
    if (!%hl.tips) { noop $input(Please enable Highlight Tips.,o) }
    else {
      if ($me isop $active) {
        var %a = 1
        while (%a <= $did(4).lines) {
          bs say $active $did($dname,4,%a).text
          inc %a
        }
      }
    }
  }
  if ($did == 10) || ($did == 11) {
    dialog -x hlmanager hlmanager
  }
}

on *:DIALOG:hlmanager:menu:2: {
  dialog -x hlmanager hlmanager
}

alias -l highlightmanager {
  dialog $iif($dialog(hlmanager),-v,-m hlmanager) hlmanager
}


I had an idea to make a New Highlight Manager.. other than mIRC's in built one...

So.. Here it is..

When it is not enabled it will look like Image

And when it is.. It will look like Image

Updated: Fixed an error found by DragonHeart.

Updated again: Added a "Clear Window" menu it's a right click menu.. It will be located at the top of the menu.

Update: Replaced the "Clear HL" Button for a "Edit HL" button.
Last edited by GrimReaper on Thu Feb 24, 2011 11:25 pm, edited 7 times in total.
GrimReaper
 
Posts: 73
Joined: Wed Oct 28, 2009 4:34 pm
Location: In your router, Resetting your connection.

Re: mIRC highlight manager

Postby therock247uk » Mon Aug 16, 2010 4:22 pm

i like!!
therock247uk
 
Posts: 265
Joined: Thu Oct 22, 2009 8:29 pm
Location: uk

Re: mIRC highlight manager

Postby shaggysi0 » Mon Aug 16, 2010 5:16 pm

good stuff Danneh :) very useful and soo easy to configure.
shaggysi0
 
Posts: 19
Joined: Thu Oct 29, 2009 7:06 pm

Re: mIRC highlight manager

Postby GrimReaper » Mon Aug 16, 2010 6:36 pm

Thanks guys. If you can think of anything that could be done to it.. Lemme know.. and I'll see what I can do :twisted:
GrimReaper
 
Posts: 73
Joined: Wed Oct 28, 2009 4:34 pm
Location: In your router, Resetting your connection.

Re: mIRC highlight manager

Postby Karol » Mon Aug 16, 2010 8:43 pm

Great job on the script Danneh.. works flawlessly.
GeekShed Helpop
Karol
 
Posts: 14
Joined: Mon Oct 26, 2009 11:17 pm
Location: Connecticut, USA

Re: mIRC highlight manager

Postby GrimReaper » Thu Aug 26, 2010 10:34 am

Added timestamp's to both the $tip's and the windows. Which was the idea of CCMike :)
GrimReaper
 
Posts: 73
Joined: Wed Oct 28, 2009 4:34 pm
Location: In your router, Resetting your connection.

Re: mIRC highlight manager

Postby DragonHeart » Thu Aug 26, 2010 10:38 am

Script works great. Love it!
User avatar
DragonHeart
 
Posts: 33
Joined: Mon Nov 23, 2009 5:52 pm
Location: Miami, Florida


Return to Script help

Who is online

Users browsing this forum: No registered users and 9 guests

cron